기본 AHK 스크립트

본 포스팅의 목적은 아래의 기능을 수행하는 AHK(Auto Hot Key) 스크립트를 제공하기 위함이다.

 

1. 103/106키보드 레이아웃을 사용하는 윈도우즈 시스템에서 한영전환을 Shift+Space로 하기

101키(종류3)에서 Shift+Space키로 한영전환하는데 익숙해져서 103/106키보드에서도 한영전환을 동일하게 하기 위해서 이 스크립트를 만들었다.

 

2. End키를 누르는 대신에 Left_Shift와 Right_Shift를 동시에 누르기

코딩을 하다보면 자동완성기능은 Tab키를 누르면 되는데 따옴표나 괄호와 같은 것에 항상 막혀서 정지한다. 이 때 이 조합을 누르면 End키를 누른것과 같이 동작해서 빠르게 현재 라인의 마지막으로 이동할 수 있다.

 

3. 줌인 줌아웃을 Ctrl+Down키와 Ctrl+Up키로 설정하기

 

컨트롤+"마우스 스크롤 휠"을 위 아래 방향으로 하면서 줌인/줌아웃 하기에는 항상 마우스를 손에 올리고 있어야 해서 키보드로 이를 수행하도록 만들었다. 물론 '-'와 '+'키를 컨트롤키와 조합해서 사용해도 되나, 둘이 붙어 있어 시각 지원이 있어야 한다. 그래서 눈으로 확인 안해도 되는 화살표 키버튼을 이용했다.

 

4. 열려있는 모든 토탈커맨더를 "WIN+F12"로 프론트로 가져오기와 원래위치로 보내기

 

문서 작업을 하다보면 폴더를 빠르게 브라우징해야 할 경우가 많다. 참조파일도 보고, 복사하고, 이동하고, 폴더 만들고... 이런 작업들은 보통 본인은 토탈커맨더에서 수행한다.

그런데 보통 화면에 최소 5개 이상의 창을 띄어놓고 작업한다. 그러다 토탈커맨더가 필요할 때가 있는데 토탈커맨더도 여러개 띄어서 사용하다가 어느게 내가 작업하던 폴더를 보여주는 토탈커맨더인지 몰라 화면 아래의 작업 트레이에 마우스를 올려서 찾는 것이 너무 번거러워졌다.

이럴 때 이 스크립트를 추가해서 이 핫키(WIN+F12)를 누르면 열려져 있던 모든 토탈커맨더가 프론트창으로 이동, 그 내용을 바로 확인할 수 있게된다. 또한 동일 키(WIN+F12)를 한 번 더 누르면 토탈커맨더를 모두 내릴 수 있어 작업중이던 프로그램으로 바로 돌아가 기존의 작업을 그대로 이어갈 수 있다.

 

아래는 AHK V2로 만들어진 스크립트이다. 

#Requires AutoHotkey v2.0

;Shift+SpaceBar: 한영전환
+Space::SendInput("{vk15}")

;왼쪽/오른쪽 shift를 누르면 프람프트가 마지막으로 이동
LShift & RShift::{
    Send("{End}")
}

;줌인/줌아웃 기능->다른 핫키로 변경함
;^Up::Send("^=") ; Ctrl + 위쪽 화살표 -> Ctrl + - (줌 인)
;^Down::Send("^-") ; Ctrl + 아래쪽 화살표 -> Ctrl + = (줌 아웃)

;일부 에디터에서 Ctrl+Up/Down키가 다른 용도로 사용되어서 위와 같이 변경 함.
;추가일 2025-03-21
^Up::Send("^{WheelUp}") ; Ctrl + 위쪽 화살표 -> Ctrl + WheelUp (줌 인)
^Down::Send("^{WheelDown}") ; Ctrl + 아래쪽 화살표 -> Ctrl + WheelDown (줌 아웃)

;WIN+F12: 빠르게 토탈커맨더를 보고 싶을 때 아래의 코드를 삽입한다.
;추가일 2025-04-04
#F12:: {
    static tcVisible := false

    if (!tcVisible) {
        ; 현재 상태가 숨겨진 상태이면, 모든 창 최소화 후 Total Commander 창 복원
        WinMinimizeAll()
        Sleep 100  ; 잠깐 대기

        tcWindows := WinGetList("ahk_exe TOTALCMD64.EXE")
        for win in tcWindows {
            WinRestore(win)
        }
        if (tcWindows.Length > 0)
            WinActivate(tcWindows[1])
        
        tcVisible := true
    } else {
        ; 이미 토탈커맨더 창이 보이는 상태이면, 해당 창들을 최소화하여 원래 위치(최소화 상태)로 돌림
        tcWindows := WinGetList("ahk_exe TOTALCMD64.EXE")
        for win in tcWindows {
            WinMinimize(win)
        }
        tcVisible := false
    }
}

 

파일을 만들고 바로가기 생성 후, 이 바로가기를 사용자의 자동실행폴더

C:\Users\[사용자 이름]\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup

에 넣어 놓으면 된다.

그림. 폴더의 위치와 바로가기 파일

 

물론 AHK는 인스톨 한 후에!

https://www.autohotkey.com/

AutoHotkey